home *** CD-ROM | disk | FTP | other *** search
/ Amiga Games: Greatest Hits 1996 / Amiga Games: Greatest Hits 1996.iso / userbox / publicdomain / edspell / install / edspell_install < prev    next >
Text File  |  1996-07-28  |  4KB  |  175 lines
  1. ;
  2. ; ********************************************************************
  3. ; **                                                                **
  4. ; **  Script Name : EdSpell_Install                                 **
  5. ; **       Author : Martin Reddy                                    **
  6. ; **         Date : 28/7/96                                         **
  7. ; **      Purpose : Installs the EdSpell package on to a harddrive  **
  8. ; **                using the official CMB installer                **
  9. ; **   Background : Stuff that's not in the foreground              **
  10. ; **      Credits : Hi Mum!                                         **
  11. ; **                                                                **
  12. ; ********************************************************************
  13. ;
  14.  
  15. ; **
  16. ; ** First of all we will define some constants for the script...
  17. ; **
  18.  
  19. (set DefaultDest "DH0:EdWord")
  20.  
  21. ; **
  22. ; ** Now we will find out where the package is to be installed to...
  23. ; ** The variable Destination will hold the directory name
  24. ; **
  25.  
  26. (set Destination 
  27.     (askdir
  28.         (prompt "Please select the directory where your "
  29.             "installation of EdWord lives. A directory "
  30.                "called EdSpell will be created there.")
  31.         (newpath)
  32.         (default DefaultDest)
  33.         (help "You must tell me where you want to install "
  34.               "the EdSpell package. This should normally "
  35.               "be the root directory where your EdWord "
  36.               "Professional installation is.\n\n"
  37.               "If you have your EdWord installation in "
  38.               "DH0:EdWord/ then a directory called EdSpell "
  39.               "will be created inside this directory in "
  40.               "order to hold all of the EdSpell files.")
  41.     )
  42. )
  43.  
  44. ; **
  45. ; ** Work out the destination directory name and create it
  46. ; **
  47.  
  48. (set @default-dest Destination)
  49. (set Destination (tackon Destination "EdSpell"))
  50.  
  51. (makedir Destination)
  52.  
  53. ; **
  54. ; ** Copy the EdSpell ARexx scripts
  55. ; **
  56.  
  57. (
  58.     (set RexxDrawer (tackon Destination "Rexx"))
  59.     (copyfiles
  60.         (prompt "Copying ARexx Scripts...")
  61.         (help @copyfiles-help)
  62.         (source "/Rexx")
  63.         (dest RexxDrawer)
  64.         (all)
  65.     )
  66. )
  67.  
  68. ; **
  69. ; ** Copy the DelWord utility and source code
  70. ; **
  71.  
  72. (
  73.     (set UtilsDrawer (tackon Destination "Utils"))
  74.     (copyfiles
  75.         (prompt "Copying DelWord utility...")
  76.         (help @copyfiles-help)
  77.         (source "/Utils")
  78.         (dest UtilsDrawer)
  79.         (all)
  80.     )
  81. )
  82.  
  83. ; **
  84. ; ** Copy the default dictionary
  85. ; **
  86.  
  87. (
  88.     (set DictDrawer (tackon Destination "Dict"))
  89.     (copyfiles
  90.         (prompt "Copying dictionary files...")
  91.         (help @copyfiles-help)
  92.         (source "/Dict")
  93.         (dest DictDrawer)
  94.         (all)
  95.     )
  96. )
  97.  
  98. ; **
  99. ; ** Copy the ISpell stuff
  100. ; **
  101.  
  102. (
  103.     (set ISpellDrawer (tackon Destination "ISpell"))
  104.     (copyfiles
  105.         (prompt "Copying ISpell files...")
  106.         (help @copyfiles-help)
  107.         (source "/ISpell")
  108.         (dest ISpellDrawer)
  109.         (all)
  110.     )
  111. )
  112.  
  113. ; **
  114. ; ** Copy the AmigaGuide help file (and it's icon)
  115. ; **
  116.  
  117. (copyfiles
  118.     (prompt "Copying AmigaGuide Help file...")
  119.     (help @copyfiles-help)
  120.     (source "/EdSpell.guide")
  121.     (dest Destination)
  122.     (infos)
  123. )
  124.  
  125. ; **
  126. ; ** copy the default icon for the EdSpell directory
  127. ; **
  128.  
  129. (set ParentDir (expandpath (tackon Destination "/")))
  130. (copyfiles
  131.     (source "EdSpell.icon")
  132.     (dest ParentDir)
  133.     (newname "EdSpell.info")
  134. )
  135.  
  136. ; **
  137. ; ** Now we want to add the assign EdSpell: to the user's startup
  138. ; **
  139.  
  140. (startup
  141.     (prompt 
  142.         (("Add \"Assign EdSpell: %s\" to \"S:user-startup\"? (see help for more)" Destination))
  143.     )
  144.     ("EdSpell")
  145.     (help    
  146.         ("Select the Proceed button to add the line ")
  147.         ("\"Assign EdSpell: %s\" " Destination)
  148.         ("to your user startup file. The various EdSpell ")
  149.         ("ARexx scripts require this assign to be available ")
  150.         ("in order to operate.\n\n")
  151.         @startup-help)
  152.     (command ("Assign EdSpell: %s" Destination))
  153. )
  154.  
  155. ; **
  156. ; ** setup an assign to EdSpell: now so that we don't need to reboot 
  157. ; **
  158.  
  159. (makeassign "EdSpell" Destination)
  160.  
  161. ; **
  162. ; ** All done, so let's say goodbye...
  163. ; **
  164.  
  165. (exit "The EdSpell package is now ready to use\n"
  166.       "(you don't need to reboot).\n\n"
  167.       "Just run EdWord and try calling one of "
  168.       "ARexx scripts via the \"Run Script\" menu "
  169.       "option.\n\n"
  170.       "(All EdSpell ARexx scripts can be found "
  171.       "in \"EdSpell:Rexx/\")" )
  172.  
  173. ; *** EOF: EdSpell_Install ***
  174.  
  175.