home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Amiga Games: Greatest Hits 1996
/
Amiga Games: Greatest Hits 1996.iso
/
userbox
/
publicdomain
/
edspell
/
install
/
edspell_install
< prev
next >
Wrap
Text File
|
1996-07-28
|
4KB
|
175 lines
;
; ********************************************************************
; ** **
; ** Script Name : EdSpell_Install **
; ** Author : Martin Reddy **
; ** Date : 28/7/96 **
; ** Purpose : Installs the EdSpell package on to a harddrive **
; ** using the official CMB installer **
; ** Background : Stuff that's not in the foreground **
; ** Credits : Hi Mum! **
; ** **
; ********************************************************************
;
; **
; ** First of all we will define some constants for the script...
; **
(set DefaultDest "DH0:EdWord")
; **
; ** Now we will find out where the package is to be installed to...
; ** The variable Destination will hold the directory name
; **
(set Destination
(askdir
(prompt "Please select the directory where your "
"installation of EdWord lives. A directory "
"called EdSpell will be created there.")
(newpath)
(default DefaultDest)
(help "You must tell me where you want to install "
"the EdSpell package. This should normally "
"be the root directory where your EdWord "
"Professional installation is.\n\n"
"If you have your EdWord installation in "
"DH0:EdWord/ then a directory called EdSpell "
"will be created inside this directory in "
"order to hold all of the EdSpell files.")
)
)
; **
; ** Work out the destination directory name and create it
; **
(set @default-dest Destination)
(set Destination (tackon Destination "EdSpell"))
(makedir Destination)
; **
; ** Copy the EdSpell ARexx scripts
; **
(
(set RexxDrawer (tackon Destination "Rexx"))
(copyfiles
(prompt "Copying ARexx Scripts...")
(help @copyfiles-help)
(source "/Rexx")
(dest RexxDrawer)
(all)
)
)
; **
; ** Copy the DelWord utility and source code
; **
(
(set UtilsDrawer (tackon Destination "Utils"))
(copyfiles
(prompt "Copying DelWord utility...")
(help @copyfiles-help)
(source "/Utils")
(dest UtilsDrawer)
(all)
)
)
; **
; ** Copy the default dictionary
; **
(
(set DictDrawer (tackon Destination "Dict"))
(copyfiles
(prompt "Copying dictionary files...")
(help @copyfiles-help)
(source "/Dict")
(dest DictDrawer)
(all)
)
)
; **
; ** Copy the ISpell stuff
; **
(
(set ISpellDrawer (tackon Destination "ISpell"))
(copyfiles
(prompt "Copying ISpell files...")
(help @copyfiles-help)
(source "/ISpell")
(dest ISpellDrawer)
(all)
)
)
; **
; ** Copy the AmigaGuide help file (and it's icon)
; **
(copyfiles
(prompt "Copying AmigaGuide Help file...")
(help @copyfiles-help)
(source "/EdSpell.guide")
(dest Destination)
(infos)
)
; **
; ** copy the default icon for the EdSpell directory
; **
(set ParentDir (expandpath (tackon Destination "/")))
(copyfiles
(source "EdSpell.icon")
(dest ParentDir)
(newname "EdSpell.info")
)
; **
; ** Now we want to add the assign EdSpell: to the user's startup
; **
(startup
(prompt
(("Add \"Assign EdSpell: %s\" to \"S:user-startup\"? (see help for more)" Destination))
)
("EdSpell")
(help
("Select the Proceed button to add the line ")
("\"Assign EdSpell: %s\" " Destination)
("to your user startup file. The various EdSpell ")
("ARexx scripts require this assign to be available ")
("in order to operate.\n\n")
@startup-help)
(command ("Assign EdSpell: %s" Destination))
)
; **
; ** setup an assign to EdSpell: now so that we don't need to reboot
; **
(makeassign "EdSpell" Destination)
; **
; ** All done, so let's say goodbye...
; **
(exit "The EdSpell package is now ready to use\n"
"(you don't need to reboot).\n\n"
"Just run EdWord and try calling one of "
"ARexx scripts via the \"Run Script\" menu "
"option.\n\n"
"(All EdSpell ARexx scripts can be found "
"in \"EdSpell:Rexx/\")" )
; *** EOF: EdSpell_Install ***